Rez macro (1 Viewer)

[deeken]

Hey I dont really know to much about macros but I have a question for you. Recently there was a sumraid macro made and its been working great so far for me. Was curious would it be possible to make a rez raid macro? Where it summons a corpse to you, then rezzes it? Or somthing like that.

 

[Pugs]

This should work you need spell cast inc other than that it is ready to go.
Ps if you want to use the 1.0 just put
"/call Cast "Water Sprinkler of Nem Ankh "" item were "/call cast "rez"" is.
make sure it is equiped.

|Sumraid.mac
|By Mochila 
|rez added by Pugs
|must have spellcast.inc |http://www.macroquest2.com/phpBB2/viewtopic.php?t=6748 page 3
#include spellcast.inc

Sub Main

  /declare Raidlist[72] string outer NULL
  /declare raidnumb int outer 1
  /declare numbinraid int outer 0
 
  /varset numbinraid ${Raid.Members}

:loop
   /if (${raidnumb}<${numbinraid} || ${raidnumb}==${numbinraid}) {     
     /varset Raidlist[${raidnumb}] ${Raid.Member[${raidnumb}]}
   /target ${Raidlist[${raidnumb}]}'s corpse
   /delay 2
   /docommand /sum
   /delay 3
   /call cast "Resurrection"
   /varcalc raidnumb ${raidnumb}+1
   /goto :loop
   /if (${raidnumb}>${numbinraid}) {
   /target clear
   /delay 2
   /echo Done dragging the raid.
}

/return

Spell cast.inc

|| SpellCast.inc
|| Last Modified: 5/14/2004 9:30pm
| This will cast a spell reliably for you...
|| Usage:
|       /call Cast "spellname|itemname|AA#|AAskillname" |[item|activate|gem#] [nocheck|dismount|nodismount]
| If no dismount or nodismount is provided it defaults to nodismount.
| This would essentially: /cast "Death Peace"
| example: /call Cast "Death Peace"
| This would essentially: Check for the spell in your spell slots, if not there  |mem it to spell
|                         gem slot 7 and then /cast "Death Peace"
| example: /call Cast "Death Peace" gem7
|
| This would essentially: /cast item "White Rope Bridle"
| example: /call Cast "White Rope Bridle" item
|
| This would essentially: /alt activate 169
| example: /call Cast "169" activate
|  or...
| example: /call Cast "Divine Arbitration" activate
|
| This would dismount if your target was lost or dies mid-cast, cast Burn and mem it to spell
| slot 3 if it wasn't already memmed:
| example: /call Cast "Burn" gem3 dismount
|
| This would not dismount but would move you back and forth if your target was lost or dies mid-cast, cast Burn and mem
| it to spell slot 3 if it wasn't already memmed:
| example: /call Cast "Burn" gem3 nodismount
|
| 'nocheck' is the default for the "loss of target/target dying" value.  If nocheck is specified (Or nothing was specified)
| no target checking will be performed and spellcast.inc should act like the spellcast.inc of the past.
|
| It will return the following values:
| CAST_SUCCESS
| CAST_UNKNOWNSPELL
| CAST_OUTOFMANA
| CAST_OUTOFRANGE
| CAST_CANNOTSEE
| CAST_STUNNED
| CAST_RESISTED
| CAST_TOOK2LONG
| CAST_ABILITYNOTREADY
| CAST_IMMUNESLOW
| CAST_LOSTTARGET
|
| New Vars Modification
| Plazmic's no globals needed version
|
| Oct 09, 2003 - Updated to work with new vars and $char(casting) -gf
| Oct 11, 2003 - switched some logic, removed defines -gf
| Oct 15, 2003 - Item support added by -EqMule
| XXX xx, xxxx - Modified to add automeming of spells. -Goofmester1
| Dec 26, 2003 - fd fail 1 added -m0nk
| Jan 01, 2004 - timeout(5s) added to stop "dead-time" -m0nk
| Jan 01, 2004 - switchd fdfail to a standing check. -m0nk
| Jan 01, 2004 - added silence checking as a stun check -m0nk
| Feb 17, 2004 - added AA activate capabilities -ml2517
| Apr 11, 2004 - Updated for new Parm system -ml2517
| Apr 12, 2004 - Will spit out a different message on immune to slows. -ml2517
| Apr 16, 2004 - Removed /sendkeys and replaced with /keypress. -ml2517
| Apr 17, 2004 - Various code enhancements. -Wassup
| Apr 20, 2004 - Updated all of the /if's to have parenthesis. -ml2517
| Apr 25, 2004 - Updated to new variable system. -ml2517
| Apr 29, 2004 - Fixed Item problem -ml2517
| Apr 29, 2004 - Changed the alt ability to use AltAbilityReady instead of an event. -ml2517
| May 02, 2004 - Added the ability to specify a gem slot to mem spells to. -ml2517
| May 10, 2004 - Updated for new event system.
| May 12, 2004 - Added suggestions for loss of target and stun handling change. -ml2517
| May 13, 2004 - Activate now accepts AA skill by name or number. -ml2517
| May 14, 2004 - Added the nocheck value, it is the default. This bypasses the target checking code. -ml2517
|

#event Fizzle "#*#Your spell fizzles#*#"
#event Interrupt "#*#Your casting has been interrupted#*#"
#event Interrupt "#*#Your spell is interrupted.#*#"
#event Recover "#*#You haven't recovered yet...#*#"
#event Recover "#*#Spell recovery time not yet met.#*#"
#event Resisted "#*#Your target resisted the #*#"
#event OutOfMana "#*#Insufficient Mana to cast this spell!#*#"
#event OutOfRange "#*#Your target is out of range, get closer!#*#"
#event NoLOS "#*#You cannot see your target.#*#"
#event Stunned "#*#You cannot cast while stunned#*#"
#event Stunned "#*#You *CANNOT* cast spells, you have been silenced!#*#"
#event Standing "#*#You must be standing to cast a spell#*#"
#event Standing "#*#has fallen to the ground.#*#"
#event Collapse "#*#Your gate is too unstable, and collapses.#*#"
#event ImmuneSlow "#*#Your target is immune to changes in its attack speed.#*#"


Sub Cast(SpellName,ItemFlag,DismountFlag)
   /declare HaveTarget int local 0
   /declare CastBarTime timer local
   /declare CastCurrLocY float local 0
   /declare CastCurrLocX float local 0
   /varset CastCurrLocY ${Me.Y}
   /varset CastCurrLocX ${Me.X}
   /if (${Target.ID}>0) /varset HaveTarget 1
   /if (!${Defined[CastGiveUpTime]}) /declare CastGiveUpTime timer local
   /if (!${Defined[ItemFlag]}) /declare ItemFlag string local
   /if (!${Defined[DismountFlag]}) {
       /declare DismountFlag string local nocheck
       /if (${ItemFlag.Find["dismount"]}) /varset DismountFlag ${ItemFlag}
   }
   /if (!${Me.Standing} && !${Me.Mount.ID}>0) /stand
   /if (${Me.Moving}) {
       /keypress forward
       /keypress back
       /delay 8
   } else {
       /delay 4
   }
   /if (${ItemFlag.Equal["Item"]} || ${ItemFlag.Equal["Activate"]}) /goto :StartCast

   /if (!${Me.Gem["${SpellName}"]}) {
       /if (${ItemFlag.Find[gem]}) {
           /if (${Int[${ItemFlag.Right[1]}]}>0 && ${Int[${ItemFlag.Right[1]}]}<9) {
               /memspell ${ItemFlag.Right[1]} "${SpellName}"
               /delay 5s
           } else {
               /goto :GenericMem
           }
       } else {       
           :GenericMem
           /memspell 5 "${SpellName}"
           /delay 5s
       }

   }
   :StartCast
      /varset CastGiveUpTime 5s
   :CastNow
      /if (${ItemFlag.Equal["Item"]}) {
         /call ClearReturnValue
         /cast item "${SpellName}"
      } else /if (${ItemFlag.Equal["Activate"]}) {
         /call ClearReturnValue
         /if (!${Me.AltAbilityReady[${SpellName}]}) /return CAST_ABILITYNOTREADY
         /alt activate ${AltAbility[${SpellName}].ID}
         /varset CastBarTime ${Me.Casting.CastTime}
      } else {
         /if (!${Me.Gem["${SpellName}"]}) /return CAST_UNKNOWNSPELL
         /call ClearReturnValue
         /if (!${Me.SpellReady["${SpellName}"]}) {
            /if (${CastGiveUpTime}==0) /return CAST_TOOK2LONG
            /delay 1
            /goto :CastNow
         }
         /cast "${SpellName}"
         /varset CastBarTime ${Math.Calc[${Me.Casting.CastTime}*10]}
      }
   :WaitCast
      /if (${Me.Casting.ID}) {
         /if ((!${Target.ID}>0 || ${Target.Type.Equal[CORPSE]}) && !${DismountFlag.Find[nocheck]} && ${HaveTarget}==1) {
             /if (${Me.Mount.ID}>0) {
                 /if (${DismountFlag.Equal[dismount]}) {
                     /dismount
                 } else {
                     /if (!${ItemFlag.Equal["Item"]}) {
                         /if (${CastBarTime}<7) {
                             :Interrupt
                             /keypress FORWARD hold
                             /delay 6
                             /keypress FORWARD
                             /keypress BACK hold
                             /delay 8
                             /keypress BACK
                         } else {
                             :HoldForSpell
                             /delay 1
                             /if (${CastBarTime}<7) /goto :Interrupt
                             /goto :HoldForSpell
                         }
                     } else {
                         /keypress FORWARD hold
                         :Forward
                         /delay 1
                         /if (${Math.Distance[${CastCurrLocY},${CastCurrLocX}]}<6) /goto :Forward
                         /keypress FORWARD
                         /keypress BACK hold
                         :Backward
                         /delay 1
                         /if (${Math.Distance[${CastCurrLocY},${CastCurrLocX}]}>4) /goto :Backward
                         /keypress BACK
                         /if (!${Me.Casting.ID}>0) /goto :DuckTime
                     }
                 }
             }
             :DuckTime
             /keypress FORWARD
             /keypress BACK
             /if (!${Me.Ducking}) /keypress DUCK
             /delay 1
             /if (${Me.Ducking}) /keypress DUCK
             /return CAST_LOSTTARGET
         }
         /delay 1
         /goto :WaitCast
      }
   /delay 4
   /doevents Fizzle
   /doevents Interrupt
   /doevents Interrupt
   /doevents Recover
   /doevents Standing
   /doevents OutOfRange
   /doevents OutOfMana
   /doevents NoLOS
   /doevents Resisted
   /doevents ImmuneSlow
   /doevents Stunned
   /doevents Collapse
   /delay 1
   /if (${Macro.Return.Equal["CAST_RESTART"]}) /goto :StartCast
   /if (!${Macro.Return.Equal["NULL"]}) /return ${Macro.Return}
/return CAST_SUCCESS

Sub ClearReturnValue
/return NULL

Sub Event_Fizzle
/return CAST_RESTART

Sub Event_Interrupt
/return CAST_RESTART

Sub Event_Recover
   /delay 5
/return CAST_RESTART

Sub Event_Standing
   /stand
/return CAST_RESTART

Sub Event_Collapse
/return CAST_RESTART

Sub Event_OutOfMana
/return CAST_OUTOFMANA

Sub Event_OutOfRange
/return CAST_OUTOFRANGE

Sub Event_NoLOS
/return CAST_CANNOTSEE

Sub Event_Stunned
   /delay 2s !${Me.Stunned}
/return CAST_RESTART

Sub Event_Resisted
/return CAST_RESISTED

Sub Event_ImmuneSlow
/return CAST_IMMUNESLOW

 

[deeken]

Awesome thanks a lot bro

 

[deeken]

Hmm Didnt seem to work let me make sure I have this right

|Sumraid.mac
|By Mochila 
|rez added by Pugs
|must have spellcast.inc |http://www.macroquest2.com/phpBB2/viewtopic.php?t=6748 page 3
#include spellcast.inc

Sub Main

  /declare Raidlist[72] string outer NULL
  /declare raidnumb int outer 1
  /declare numbinraid int outer 0
 
  /varset numbinraid ${Raid.Members}

:loop
   /if (${raidnumb}<${numbinraid} || ${raidnumb}==${numbinraid}) {     
     /varset Raidlist[${raidnumb}] ${Raid.Member[${raidnumb}]}
   /target ${Raidlist[${raidnumb}]}'s corpse
   /delay 2
   /docommand /sum
   /delay 3
   /call Cast "Water Sprinkler of Nem Ankh"
   /varcalc raidnumb ${raidnumb}+1
   /goto :loop
   /if (${raidnumb}>${numbinraid}) {
   /target clear
   /delay 2
   /echo Done dragging the raid.
}

/return

Since im using epic do i still need the spellcast.inc?

 

[Mochila]

I liked the edit to my little Sumraid macro. As long as you're not moving around once you activate the macro, no you don't need spellcast.inc.

|Rezraid.mac
|By Mochila 

Sub Main

  /declare Raidlist[72] string outer NULL
  /declare raidnumb int outer 1
  /declare numbinraid int outer 0
 
  /varset numbinraid ${Raid.Members}

:loop
   /if (${raidnumb}<${numbinraid} || ${raidnumb}==${numbinraid}) {     
     /varset Raidlist[${raidnumb}] ${Raid.Member[${raidnumb}]}
   /target ${Raidlist[${raidnumb}]}'s corpse
   /delay 2s
   /docommand /sum
   /delay 3s
   /itemnotify mainhand rightmouseup
   /delay 10.1s
   /varcalc raidnumb ${raidnumb}+1
   /goto :loop
   /if (${raidnumb}>${numbinraid}) {
   /target clear
   /delay 2
   /echo Done dragging the raid.
}

/return

Edit: I changed the edited copy of mine to automatically right click your primary slot item. This macro *Assumes* you have cleric epic 1.0. I also added a delay after the click so it has time to cast before pulling in more corpses.

If you do not have cleric epic 1.0 All you need to do is change the following line :

 /itemnotify mainhand rightmouseup

to

/cast "Reviviscence"

You must have the spell that you list, already memorized.

Edit#2: Writing a pure rez raid macro now, if the corpses have already been dragged and you just don't wanna click...and you wanna sit on your mount afk while rezzing everyone in order...etc......But give me feedback on this

 

[deeken]

Ill give it a try tommorow raid is over for tonight appreciate your work bud

 

[Pugs]

   /call Cast "Water Sprinkler of Nem Ankh"

Since im using epic do i still need the spellcast.inc?

You need to put item after it like

/call Cast "Water Sprinkler of Nem Ankh" item

 

[Tone]

Summoning a bunch of guildies in a pile and rezing is goin to lead to questioning :P It would be better to make it not summon and just rez at the camp where rogues drug the bodies. That's just what I think but what do I know !

 

[Pugs]

I just checked my descrsion at the door on this i guess but ya it would raise a few eyebrows.

 

[Mochila]

Yeah tone...doing rezraid macro now havent got to put much work into it...Gf being a bitch and alot of stuff to do IRL.....Bah RL.